***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 06, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ9P1B-AU  A K 
.param
+vc0 = 1.950e-10	   vc1 = 9.400e-12        vc2 = 1.200	 	 vc3 = 6.000e-14	vc4 = 5.800e-1
+tc1 = 1.800e-2	           tc2 = 8.071e-3	  tc3 = 3.001e-1  	 tc4 = 3.480e-2
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {1.926e-1*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 2.492e-22	     n = 6.932e-1          rs = 1.350e-01
+ibv = 5.0e-3		   nbv = 1.0		   bv = 9.04
+ikf = 3.337e-2             
***** capacitance parameter *****
+cjo = 5.742e-11	     m = 3.206e-1	   vj = 5.815e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		    eg = 1.137	          xti = 3
+tikf = 1.000e-9          
+tbv1 = 5.880e-4	  tbv2 = -7.000e-8
.ends PDZ9P1B-AU
*$
